Microsoft® “Roslyn”

Getting Started: Semantic Analysis

September 2012

# Prerequisites

* [Roslyn Project Overview](http://go.microsoft.com/fwlink/?LinkID=230702)
* Getting Started: Syntax Analysis

# Introduction

Today, the Visual Basic and C# compilers are black boxes – text goes in and bytes come out – with no transparency into the intermediate phases of the compilation pipeline. With the Roslyn project, tools and developers can leverage the exact same data structures and algorithms the compiler uses to analyze and understand code with confidence that that information is accurate and complete.

In this walkthrough we’ll explore the **Roslyn Symbol** and **Binding APIs**. The **Syntax API** exposes the parsers, the syntax trees themselves, and utilities for reasoning about and constructing them.

# Understanding Compilations and Symbols

The **Syntax API** allows you to look at the *structure* of a program. However, often you’ll want richer information about the semantics or *meaning* of a program. And while a loose code file or snippet of VB or C# code can be syntactically analyzed in isolation it’s not very meaningful to ask questions such as “what’s the type of this variable” in a vacuum. The meaning of a type name may be dependent on assembly references, namespace imports, or other code files. That’s where the **Compilation** class comes in.

A **Compilation** is analogous to a single project as seen by the compiler and represents everything needed to compile a Visual Basic or C# program such as assembly references, compiler options, and the set of source files to be compiled. With this context you can reason about the meaning of code. **Compilations** allow you to find **Symbols** – entities such as types, namespaces, members, and variables which names and other expressions refer to. The process of associating names and expressions with **Symbols** is called **Binding**.

### Example – Creating a compilation

This example shows how to create a **Compilation** by adding assembly references and source files. Like the syntax trees, everything in the Symbols API and the Binding API is immutable.

1. Create a new VB Roslyn Console Application project.
   * In Visual Studio, choose File -> New -> Project… to display the New Project dialog.
   * Under Visual Basic -> **Roslyn**, choose “Console Application”.
   * Name your project “**SemanticsVB**” and click OK.
2. Replace the contents of your **Module1.vb** with the following:

Option Strict Off  
  
Module Module1  
   
    Sub Main()  
   
        Dim sourceText As String =  
<String>  
Imports System  
Imports System.Collections.Generic  
Imports System.Text  
   
Namespace HelloWorld  
    Class Class1  
        Shared Sub Main(args As String())  
            Console.WriteLine("Hello, World!")  
        End Sub  
    End Class  
End Namespace  
</String>  
   
        Dim tree = SyntaxTree.ParseText(sourceText)  
   
        Dim root As CompilationUnitSyntax = tree.GetRoot()  
    End Sub  
   
End Module

* + Some readers may run with **Option Strict** turned **On** by default at the project level. Turning **Option Strict** **Off** in this walkthrough simplifies many of the examples by removing much of the casting required.

1. Next, add this code to the end of your **Main** method to construct a **Compilation** object:

        Dim compilation As Compilation =   
 compilation.Create("HelloWorld").  
                            AddReferences(MetadataReference.CreateAssemblyReference("mscorlib")).  
                            AddSyntaxTrees(tree)

1. Move your cursor to the line containing the **End Sub** statement of your **Main** method and press F9 to set a breakpoint there.
2. Press F5 Run the program.
3. Hover over the compilation variable and expand the datatips to inspect the **Compilation** object in the debugger.

# The SemanticModel

Once you have a **Compilation** you can ask it for a **SemanticModel** for any **SyntaxTree** contained in that **Compilation**. **SemanticModels** can be queried to answer questions like “What names are in scope at this location?” “What members are accessible from this method?” “What variables are used in this block of text?” and “What does this name/expression refer to?”

### Example – Binding a name

This example shows how to obtain a **SemanticModel** object for our HelloWorld **SyntaxTree**. Once the model is obtained, the name in the first **Imports** statement is bound to retrieve a **Symbol** for the **System** namespace.

1. Add this code to the end of your Main method. The code gets a **SemanticModel** for the HelloWorld **SyntaxTree** and stores it in a new variable:

        Dim model = compilation.GetSemanticModel(tree)

1. Move your cursor to this line and press Ctrl+Shift+F10 to set this as the next statement to be executed. Press F10 to execute the statement and initialize the new variable. You will need to repeat this process for each of the following steps as we introduce new variables and inspect them with the debugger.
2. Now add this code to bind the **Name** of the “**Imports System**” statement using the **SemanticModel.GetSymbolInfo** method:

        Dim firstImport As MembersImportsClauseSyntax =   
 root.Imports(0).ImportsClauses(0)  
   
        Dim nameInfo = model.GetSymbolInfo(firstImport.Name)

1. Execute these statements and hover over the **nameInfo** variable and expand the datatip to inspect the **SymbolInfo** object returned.

* Note the **Symbol** property. This property returns the **Symbol** this expression refers to. For expressions which don’t refer to anything (such as numeric literals) this property will be null.
  + Note that the **Symbol.Kind** property returns the value **SymbolKind.Namespace**.

1. Cast the symbol to a **NamespaceSymbol** instance and store it in a new variable:

        Dim systemSymbol As NamespaceSymbol = nameInfo.Symbol

1. Execute this statement and examine the **systemSymbol** variable using the debugger datatips.
2. Add the following code to enumerate the sub-namespaces of the **System** namespace and print their names to the **Console**:

        For Each ns In systemSymbol.GetNamespaceMembers()  
            Console.WriteLine(ns.Name)  
        Next

1. Press Shift+F5 to stop the program.
2. Press Ctrl+F5 to run the program. You should see the following output:

Collections  
Configuration  
Deployment  
Diagnostics  
Globalization  
IO  
Reflection  
Resources  
Runtime  
Security  
StubHelpers  
Text  
Threading  
Press any key to continue . . .

### Example – Binding an expression

The previous example showed how to bind name to find a **Symbol**. However, there are other expressions in a VB program that can be bound that aren’t names. This example shows how binding works with other expression types - in this case a simple string literal.

1. Add the following code to locate the “**Hello, World!**” string literal in the **SyntaxTree** and store it in a variable (it should be the only **LiteralExpressionSyntax** in this example):

        Dim helloWorldString = root.DescendantNodes().  
 OfType(Of LiteralExpressionSyntax)().  
 First()

1. Press F5 to run the program.
2. Add the following code to get the **TypeInfo** for this expression:

        Dim literalInfo = model.GetTypeInfo(helloWorldString)

1. Execute this statement and examine the **literalInfo**.
   * Note that its **Type** property is not null and returns the **NamedTypeSymbol** for the **System.String** type because the string literal expression has a compile-time type of **System.String**
2. Press Shift+F5 to stop the program.
3. Add the following code to enumerate the public methods of the **System.String** class which return strings and print their names to the **Console**:

        Dim stringTypeSymbol As NamedTypeSymbol = literalInfo.Type  
   
        Dim methodNames = From method In stringTypeSymbol.GetMembers().  
                                                          OfType(Of MethodSymbol)()  
                          Where method.ReturnType = stringTypeSymbol AndAlso  
                                method.DeclaredAccessibility = Accessibility.Public  
                          Select method.Name Distinct  
   
 Console.Clear()  
        For Each name In methodNames  
            Console.WriteLine(name)  
        Next

1. Press Ctrl+F5 to run to run the program. You should see the following output:

Join  
Substring  
Trim  
TrimStart  
TrimEnd  
Normalize  
PadLeft  
PadRight  
ToLower  
ToLowerInvariant  
ToUpper  
ToUpperInvariant  
ToString  
Insert  
Replace  
Remove  
Format  
Copy  
Concat  
Intern  
IsInterned  
Press any key to continue . . .

1. Your **Module1.vb** file should now look like this:

Option Strict Off  
  
Module Module1  
   
    Sub Main()  
   
        Dim sourceText As String =  
<String>  
Imports System  
Imports System.Collections.Generic  
Imports System.Text  
   
Namespace HelloWorld  
    Class Class1  
        Shared Sub Main(args As String())  
            Console.WriteLine("Hello, World!")  
        End Sub  
    End Class  
End Namespace  
</String>  
   
        Dim tree = SyntaxTree.ParseText(sourceText)  
   
        Dim root As CompilationUnitSyntax = tree.GetRoot()  
   
        Dim compilation As Compilation =   
 compilation.Create("HelloWorld").  
                            AddReferences(MetadataReference.CreateAssemblyReference("mscorlib")).  
                            AddSyntaxTrees(tree)  
   
        Dim model = compilation.GetSemanticModel(tree)  
   
        Dim firstImport As MembersImportsClauseSyntax =   
 root.Imports(0).ImportsClauses(0)  
   
        Dim nameInfo = model.GetSymbolInfo(firstImport.Name)  
   
        Dim systemSymbol As NamespaceSymbol = nameInfo.Symbol  
   
        For Each ns In systemSymbol.GetNamespaceMembers()  
            Console.WriteLine(ns.Name)  
        Next  
   
        Dim helloWorldString = root.DescendantNodes().  
 OfType(Of LiteralExpressionSyntax)().  
 First()  
   
        Dim literalInfo = model.GetTypeInfo(helloWorldString)  
   
        Dim stringTypeSymbol As NamedTypeSymbol = literalInfo.Type  
   
        Dim methodNames = From method In stringTypeSymbol.GetMembers().  
                                                          OfType(Of MethodSymbol)()  
                          Where method.ReturnType = stringTypeSymbol AndAlso  
                                method.DeclaredAccessibility = Accessibility.Public  
                          Select method.Name Distinct  
   
 Console.Clear()  
        For Each name In methodNames  
            Console.WriteLine(name)  
        Next  
    End Sub  
   
End Module

1. Congratulations! You’ve just used the **Roslyn** **Symbol** and **Binding APIs** to analyze the meaning of names and expressions in a VB program.